Программирование Викиданных/Природоохранная зона

Статья посвящена исследованию объекта Викиданных "природоохранная зона".
С помощью SPARQL-запросов были решены следующие задачи:

Выведен список всех экземпляров объекта "природоохранная зона".
Выведен список всех экземпляров объекта "природоохранная зона", находящихся на территории России.
Построена столбчатая диаграмма, отображающая динамику изменения количества новых природоохранных зон в России и в мире по десятилетиям.
Построена пузырьковая диаграмма, отображающая соотношение количества природоохранных зон в разных странах.

Также был произведен анализ полноты Викиданных, дополнена информация у 100 экземпляров объекта "природоохранная зона".

Экземпляры объекта "Природоохранная зона"[править]

Объекты: природоохранная зона (Q473972).
Свойства: экземпляр (P31), подкласс (P279).

Построим список всех природоохранных зон.

#added 2017-02
#List of `instances of` "protected area" 
SELECT ?area ?areaLabel
WHERE
{
    ?area (wdt:P31/wdt:P279*) wd:Q473972.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}

SPARQL-запрос, 32639 записей.

Наиболее полными и проработанными природоохранными зонами на Викиданных являются: Цзючжайгоу, Кракатау, Риф Кингмен

Почти пустыми и малоинформативными природоохранными зонами оказались: Шульган-Таш (заповедник), Оренбургский заповедник, Аджлаун Форест (заказник).

Природоохранные зоны России[править]

Выведем список природоохранных зон, находящихся на территории России.

Объекты: Россия (Q159), природоохранная зона (Q473972).
Свойства: государство (P17), экземпляр (P31), подкласс (P279).

 #added 2017-03
SELECT ?area ?areaLabel        #List of `instances` ... 
WHERE
{
  ?area (wdt:P31/wdt:P279*) wd:Q473972.    # ... of "protected area" ...  
  ?area wdt:P17 wd:Q159.                   # ... belonging to "Russia"
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ru"}
}

SPARQL-запрос, 819 записей.

Природоохранные зоны по дате основания[править]

Построим гистограмму, отображающую количество оснований (созданий) природоохранных зон по десятилетиям.

Объекты: природоохранная зона (Q473972), Россия (Q159), СССР (Q15180), Российская империя (Q34266).
Свойства: дата основания/создания (P571), экземпляр (P31), государство (P17).

По всему миру[править]

#added 2017-03
#defaultView:BarChart 
SELECT (str(?decade) AS ?decade) (COUNT(?inception) AS ?quantity) # number of "inceptions" ...
WHERE {
  ?item wdt:P31 wd:Q473972. # ... of "protected areas" ...
  
  ?item wdt:P571 ?inception.
  BIND( YEAR(?inception) as ?year ) 
  BIND( FLOOR(?year/10)*10 as ?decade ) # ... per each 10 years
} 
GROUP BY ?decade 
ORDER BY ?decade

SPARQL-запрос, 12 записей.

По СССР и России[править]

#added 2017-03
#defaultView:BarChart 
SELECT (str(?decade) AS ?decade) (COUNT(?inception) AS ?quantity) # ... of the number of "inceptions" ...
WHERE {
  ?item wdt:P31 wd:Q473972. # ... of "protected areas" ...
  ?item wdt:P571 ?inception. # date of creation
  
  { ?item wdt:P17 wd:Q159 } UNION   # ... belonging to "Russia", ...
  { ?item wdt:P17 wd:Q15180 } UNION # ... "Soviet Union" ...
  { ?item wdt:P17 wd:Q34266 }       # ... and "Russian Empire" ...
  
  BIND(YEAR(?inception) as ?year ) 
  BIND( FLOOR(?year/10)*10 as ?decade ) # ... per each 10 years
  
} 
GROUP BY ?decade 
ORDER BY ?decade

SPARQL-запрос, 7 записей.

Сравнение и анализ динамики изменения количества новых природоохранных зон в России и во всём мире[править]

Сравним статистику оснований новых охраняемых природных территорий по России и по миру, укажем на их сходства:

Сокращение количества новых зон в 1940-х (три зоны) и 1960-х (12 зон) годах в мире и полное отсутствие в России. Вероятно, что причиной этому были Вторая мировая война и экстенсивное развитие экономики в 1960-x годах соответственно.
Активный рост числа заповедных территорий с начала 1970-х годов. Максимальные показатели в 1990-х годах: 12 новых зон в России, 185 в мире.
Резкое падение числа новых природоохранных зон после 2010 года (16 новых зон в мире, одна - в России). Вероятнее всего ситуация такова из-за того, что человечество уже взяло под контроль большую часть требующих того природных зон. Также, возможно, данные в Википедии могут отставать от действительности и будут введены позже.

Различия:

Резкий рост числа новых зон в 1950-х годах в мире (46 новых зон), снижение роста в России (одна новая зона - национальный парк Шульган-Таш).

Природоохранные зоны в разных странах[править]

Покажем соотношение числа природоохранных зон в разных странах мира с помощью пузырьковой диаграммы.

Объект: природоохранная зона (Q473972).
Свойства: государство (P17), экземпляр (P31), подкласс (P279).

#defaultView:BubbleChart
SELECT ?area ?country (count(*) as ?count) # number of ...
WHERE
{
	?pid (wdt:P31/wdt:P279*) wd:Q473972 . # ... "protected areas" ...
	?pid wdt:P17  ?area . # ... in different countries of the world
	OPTIONAL {
		?area rdfs:label ?country 
		filter (lang(?country ) = "en")
	}
}
GROUP BY ?area ?country
ORDER BY DESC(?count) ASC(?country)

SPARQL-запрос, 184 записи.

В результате выполнения скрипта получены 184 страны с заповедниками. Лидирующие позиции занимают Соединенные Штаты Америки (5075 зон), Германия (4921 зона), Чехия (4111 зон). Россия располагается на девятом месте (819 зон) рядом с Румынией и Словакией.

Полнота Викиданных[править]

Незаполненное свойство "дата основания"[править]

Согласно данным статьи "Природоохранная зона" Русской Википедии в мире существует 147 тысяч охраняемых территорий. В качестве авторитетного источника приведена статья В. В. Дёжкина "Особо охраняемые природные территории мира", однако ссылка является нерабочей. Эта статья была найдена в сети Интернет, но она содержит устаревшие данные за 2003 год (102 тысячи охраняемых территорий)^[1].

Согласно данным статьи "Protected area" Английской Википедии в мире существует уже 161 тысяча охраняемых территорий. В качестве авторитетного источника представлен интернет-сервис Protected Planet, управляющийся Всемирным центром мониторинга охраны окружающей среды при поддержке Международного союза охраны природы. Этот сайт является самой полной базой данных природоохранных зон, однако на данный момент позволяет получать глобальную статистику только по отдельно взятой стране. Например, по данным сервиса на территории России располагается 11,251 природоохранная зона^[2].

Также, согласно данным с сайта международного форума "IUCN World Parks Congress", в мире насчитывается около двухсот тысяч охраняемых территорий ^[3].

С помощью запроса "Экземпляры объекта природоохранная зона" мы получаем 32,639 результатов по всему миру, потому что о большинстве природоохранных зон нет записей в Викиданных, вероятно, они имеют низкую значимость. В основном это большинство составляют природоохранные зоны регионального и областного значения. Например, по данным статьи "Особо охраняемые природные территории России" Русской Википедии федеральное значение имеют только 299 особо охраняемых природных территорий.

Если обращаться к запросам "Природоохранные зоны по дате основания", то здесь результатов еще меньше. Например, по России Викиданные содержат всего 25 зон. Это связано с тем, что у большинства объектов не заполнено свойство "дата основания".

Выведем эти объекты, при помощи скрипта:

  #added 2017-03
SELECT ?area ?areaLabel ?inception        #List of `instances` ... 
WHERE
{
  ?area wdt:P31 wd:Q473972.    # ... of "protected area" ...  
  ?area wdt:P17 wd:Q159.       # ... belonging to "Russia"
  
  FILTER NOT EXISTS { ?area wdt:P571 [] }  #... with unfilled property "inception"
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ru"}
}

SPARQL-запрос, 262 записи.

В результате выполнения скрипта получен список из 262 экземпляров объекта "природоохранная зона", принадлежащих к России, с незаполненным свойством "дата основания" (до 20.03.2017).

Заполнение свойства "дата основания" у 100 объектов[править]

На 19 марта 2017 года Викиданные содержали 25 природоохранных зон по России с заполненным свойством "дата основания".

На сегодняшний день (21 мая 2017 года) Викиданные содержат 131 природоохранную зону по России с заполненным свойством "дата основания".

Будущая работа[править]

Вывести все природоохранные зоны с заполненным свойством "площадь". Отсортировать в прядке убывания.
Вывести 10 природоохранных зон, располагающихся ближе остальных к северному полюсу (а также их координаты).
Сгруппировать природоохранные зоны по странам и по свойству "категория защищённых зон IUCN". На основании полученных данных построить столбчатую диаграмму, отражающую отношение количества охраняемых зон разных категорий в каждой стране.

Упражнения[править]

	Гренландский национальный парк
	Золотые горы Алтая
	Горная гряда Хуаншань
	Национальный парк Кинабалу

	Воробьевы горы
	Кивач
	Большой Утриш
	Усть-Медведицкий природный парк

80 лет	40 лет	20 лет	10 лет
				Болоньский заповедник
				Калевальский национальный парк
				Кандалакшский заповедник
				Дубовая роща (Эсто-Алтай)