Программирование Викиданных/COVID-19

Страница посвящена исследованию географических и временных особенностей распространения вируса COVID-19 на основе анализа Викиданных.

Список вспышек эпидемий в России

List of `instances of` "disease outbreak" in Russia

#List of `instances of` "disease outbreak" in Russia
SELECT ?obj ?objLabel
WHERE
{
  ?obj wdt:P31 wd:Q3241045. # instance of "disease outbreak"
  ?obj wdt:P17 wd:Q159. # country is Russia

    SERVICE wikibase:label { bd:serviceParam wikibase:language "ru" }
}

SPARQL запрос, 47 записей.

Карта России с заражениями по регионам

Карта России с подтверждёнными случаями заражения (>10) по регионам

Map of Russia showing confirmed cases at the region, cities and republics territory level

#defaultView: Map{"hide":["?shape", "?rgb"]}
SELECT ?item ?itemLabel ?state ?stateLabel ?cases ?shape ?rgb ?time WHERE {
  wd:Q84098939 wdt:P527 ?item. 
  ?item wdt:P276 ?state ; p:P1603 ?casestmt. 
  
  ?state wdt:P3896 ?shape.
  ?casestmt ps:P1603 ?cases ; pq:P585 ?time .
  { SELECT (MAX(?cases_)/3 as ?mc) {
      wd:Q84098939 wdt:P527/wdt:P1603 ?cases_
  } }
  FILTER NOT EXISTS { ?item p:P1603/pq:P585 ?time_. FILTER(?time < ?time_) }
  BIND(IF(?cases > (9 * ?mc)/10,"290205", 
       IF(?cases > (4 * ?mc)/5,"66080f",
       IF(?cases > (7 * ?mc)/10,"a60c17", 
       IF(?cases > (3 *?mc)/5,"db0f1e",
       IF(?cases > ?mc/2,"f02937", 
       IF(?cases > (2 * ?mc)/5,"ed4e59",
       IF(?cases > (3 * ?mc)/10,"ed727a", 
       IF(?cases > ?mc/5,"f79ca2",  
       IF(?cases = 0,"ffffff",  
       "f5cbce"))))))))) as ?rgb)
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

SPARQL запрос, ? записей, используется атрибут geoshape для рисования областей России.
SPARQL запрос, 42 точки на карте с последним числом заражённых, используется атрибут coord.
SPARQL запрос, geoshape, актуальная расцветка.

Кривые по регионам России

Кривые числа заражений по регионам России

Line graph of cases by regions of Russia

#defaultView:LineChart
SELECT ?state ?time ?cases ?stateLabel {
  wd:Q84098939 wdt:P527 ?statecases. # coronavirus in Russia has parts 
  ?statecases wdt:P276 ?state ; p:P1603 ?casestmt. # location (?state) and number of cases (?casestmt)
  ?casestmt ps:P1603 ?cases ; pq:P585 ?time.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

SPARQL-запрос

Кривые числа выздоровевших по регионам России

Line graph of recoveries by regions of Russia

#defaultView:LineChart
# The number of cases of recoveries in regions of Russia by dates.
SELECT ?state ?dates ?recoveryNum ?locationLabel WHERE { 
  wd:Q84098939 wdt:P527 ?state. 
  ?state wdt:P276 ?location. 
 
  ?state p:P8010 ?recoveries.
  ?recoveries pq:P585 ?dates;
              ps:P8010 ?recoveryNum.
     
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } 
}
ORDER BY ?dates

SPARQL-запрос

Число зараженных, выздоровевших и погибших в России на каждую дату

Числа зараженных, выздоровевших и погибших от вируса COVID-19 по России

The number of cases of infection, recovery and death in Russia sorted by date.

SELECT ?item ?itemLabel ?dates ?caseNum ?deathNum ?recoveryNum  WHERE { 
  ?item wdt:P361 wd:Q84098939. 
  ?item p:P1603 ?cases.
  ?cases ps:P1603 ?caseNum;
         pq:P585 ?dates.
  OPTIONAL{ 
    ?item p:P1120 ?deaths.
    ?deaths pq:P585 ?dates;
            ps:P1120 ?deathNum.
  }  
  OPTIONAL{
    ?item p:P8010 ?recoveries.
    ?recoveries pq:P585 ?dates;
                ps:P8010 ?recoveryNum.
  }  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } 
}
ORDER BY DESC(?dates)
}

SPARQL-запрос

См. также

Литература

Narasimha Kumar G .V., Suneel Prajapati, Chitra V. Comparison of State Case Fatality and Recovery Rates of COVID-19/SARS-COV-2 in India : As of 14th April, 2020. Authorea. April 28, 2020. DOI: 10.22541/au.158809538.82380206

Ссылки

Boundaries.pl (Упрощение геометрии сложных объектов)
Number of films by year and genre (ScatterChart), анимация графика по годам
COVID-19: free live mobile-friendly visualizations for use on any website // Flourish (Визуализация данных)